Hjelp med et dialogvindu (mIRC)

[ChRIZe]

Hallo! Benytter første posten på dette forumet til dette spørsmålet: ;P

Jeg holder på med et clankampscript (for spillet Counter-Strike) til mIRC. (Laget for å gjøre søk etter dette enklere). Jeg er ganske blank på området, men etter en del tutorials har jeg fått til:

dialog pcw {
  title "PCW/CW-script"
  size -1 -1 140 205
  check "#clanmatch", 1, 10 10 75 23
  check "#seekmatch", 2, 10 30 75 23
  check "#pcw", 3, 90 10 75 23
  check "#?on?", 4, 90 30 120 23
  box "PCW/CW-innstillinger",5, 5 60 130 120
  text "Spillere", 6,  10 75 35 30, left
  combo 7,  50 75 70 100, drop %pcwsp
  text "Type", 8, 10 100 35 30, left
  combo 9, 50 100 70 100, drop %pcwtype
  text "Server",  10, 10 125 35 30,
  combo 11,50 125 70 100, drop left %pcwserv
  text "Tid", 12, 10 150 35 30, left
  Edit "", 13, 50 150 70 22, autohs %pcwtid
  button "Søk", 14, 5 185 60 20,(default, ok)
  button "Avbryt",15, 75 185 60 20,(ok)
}

alias mklst1 {
  Did -a pcw 7 2on2
  Did -a pcw 7 3on3
  Did -a pcw 7 4on4
  Did -a pcw 7 5on5
}

alias mklst2 {
  Did -a pcw 9 PCW
  Did -a pcw 9 CB
}

alias mklst3 {
  Did -a pcw 11 No server
  Did -a pcw 11 Our server
}

alias mklst {
  mklst1
  mklst2
  mklst3
}

On *:dialog:pcw:sclick:1:{ if (%pcwclanmatch == off) set %pcwclanmatch on | elseif (%pcwclanmatch == on)  set %pcwclanmatch off |  else set %pcwclanmatch off }
On *:dialog:pcw:sclick:2:{ if (%pcwseekmatch == off) set %pcwseekmatch on | elseif (%pcwclanmatch == on) set %pcwseekmatch off | else set %pcwseekmatch off }
On *:dialog:pcw:sclick:3:{ if (%pcwpcw == off) set %pcwpcw on | elseif (%pcwpcw == on) set %pcwpcw off | else set %pcwpcw off }
On *:dialog:pcw:sclick:4:{ if (%pcwxonx == off) set %pcwxonx on | elseif (%pcwxonx == on) set %pcwxonx off | else set %pcwxonx off }
On *:dialog:pcw:sclick:14:{ set %pcwtid $did(seltext,13) | set %pcwsp $did(seltext,7 | set %pcwtype $did(seltext,9) | set %pcwtype $did(seltext,9) | set %pcwserv $did(seltext,11) | pcwsrc }
On *:dialog:pcw:sclick:7:{ set %pcwsp $did(seltext,7) }
On *:dialog:pcw:sclick:9:{ set %pcwtype $did(seltext,9) }
On *:dialog:pcw:sclick:11:{ set %pcwserv $did(seltext,11) }
on 1:DIALOG:pcw:init:0: {
  mklst
  if ( %pcwclanmatch == on ) { did -c pcw 1  }
  else { did -u pcw 1 }
  if ( %pcwseekmatch == on ) { did -c pcw 2 }
  else { did -u pcw 2 }
  if (  %pcwpcw == on ) { did -c pcw 3 }
  else { did -u pcw 3 }
  if (  %pcwxonx == on ) { did -c pcw 4 }
  else { did -u pcw 4 }
}

alias pcwsrc {
  set %skt |
  if (%pcwclanmatch == on) join #clanmatch
  if (%pcwclanmatch == on) msg #clanmatch  %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
  if  (%pcwseekmatch == on) join #seekmatch
  if (%pcwseekmatch == on) msg #seekmatch  %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
  if (%pcwpcw == on) join #pcw
  if (%pcwpcw == on) msg #pcw  %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
  if (%pcwxonx == on) join #?on?
  if (%pcwxonx == on) msg #?on?  %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
}

Men prøblemet er at variablene ikke vil oppdateres når jeg klikker "SØK"-knappen, og dermed blir /msg'en til kanalene noe sånnt som: "| |" Hva er feilen her?
På forhånd TAKK!

[Scoody]

dialog pcw {
title "PCW/CW-script"
size -1 -1 140 205
check "#clanmatch", 1, 10 10 75 23
check "#seekmatch", 2, 10 30 75 23
check "#pcw", 3, 90 10 75 23
check "#?on?", 4, 90 30 120 23
box "PCW/CW-innstillinger",5, 5 60 130 120
text "Spillere", 6, 10 75 35 30, left
combo 7, 50 75 70 100, drop %pcwsp
text "Type", 8, 10 100 35 30, left
combo 9, 50 100 70 100, drop %pcwtype
text "Server", 10, 10 125 35 30,
combo 11,50 125 70 100, drop left %pcwserv
text "Tid", 12, 10 150 35 30, left
Edit "", 13, 50 150 70 22, autohs %pcwtid
button "Søk", 14, 5 185 60 20,(default, ok)
button "Avbryt",15, 75 185 60 20,(ok)
}
alias mklst1 { did -a pcw 7 2on2 | did -a pcw 7 3on3 | did -a pcw 7 4on4 | did -a pcw 7 5on5 }
alias mklst2 { did -a pcw 9 PCW | did -a pcw 9 CB }
alias mklst3 { did -a pcw 11 No server | did -a pcw 11 Our server }
alias mklst { mklst1 | mklst2 | mklst3 }
On *:dialog:pcw:sclick:1: { %pcwclanmatch = $iif(%pcwclanmatch == off,on,off) }
On *:dialog:pcw:sclick:2: { %pcwseekmatch = $iif(%pcwseekmatch == off,on,off) }
On *:dialog:pcw:sclick:3: { %pcwpcw = $iif(%pcwpcw == off,on,off) }
On *:dialog:pcw:sclick:4: { %pcwxonx = $iif(%pcwxonx == off,on,off) }
On *:dialog:pcw:sclick:14:{ set %pcwtid $did(pcw,13).text | set %pcwsp $did(pcw,7).seltext | set %pcwtype $did(pcw,9).seltext | set %pcwtype $did(pcw,9).seltext | set %pcwserv $did(pcw,11).seltext | pcwsrc }
On *:dialog:pcw:sclick:7:{ set %pcwsp $did(pcw,7).seltext }
On *:dialog:pcw:sclick:9:{ set %pcwtype $did(pcw,9).seltext }
On *:dialog:pcw:sclick:11:{ set %pcwserv $did(pcw,11).seltext }
on 1:DIALOG:pcw:init:0: {
mklst
did $iif(%pcwclanmatch == on,-c,-u) pcw 1
did $iif(%pcwseekmatch == on,-c,-u) pcw 2
did $iif(%pcwpcw == on,-c,-u) pcw 3
did $iif(%pcwxonx == on,-c,-u) pcw 4
}
alias pcwsrc {
set %skt $chr(124)
if (%pcwclanmatch == on) {
join #clanmatch
msg #clanmatch %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
}
if (%pcwseekmatch == on) {
join #seekmatch
msg #seekmatch %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
}
if (%pcwpcw == on) {
join #pcw
msg #pcw %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
}
if (%pcwxonx == on) {
join #?on?
msg #?on? %pcwsp %pcwtype %skt %pcwserv %skt %pcwtid
}
}

$did(seltext,N) funker ikke så godt, $did(pcw,N).seltext funker.
tok friheten til å optimisere scriptet litt... :D